feat(config): fish

config/fish/completions/bun.fish

@@ -0,0 +1,186 @@
+# This is terribly complicated
+# It's because:
+# 1. bun run has to have dynamic completions
+# 2. there are global options
+# 3. bun {install add remove} gets special options
+# 4. I don't know how to write fish completions well
+# Contributions very welcome!!
+
+function __fish__get_bun_bins
+	string split ' ' (bun getcompletes b)
+end
+
+function __fish__get_bun_scripts
+	set -lx SHELL bash
+	set -lx MAX_DESCRIPTION_LEN 40
+	string trim (string split '\n' (string split '\t' (bun getcompletes z)))
+end
+
+function __fish__get_bun_packages
+	if test (commandline -ct) != ""
+		set -lx SHELL fish
+		string split ' ' (bun getcompletes a (commandline -ct))
+	end
+end
+
+function __history_completions
+	set -l tokens (commandline --current-process --tokenize)
+	history --prefix (commandline) | string replace -r \^$tokens[1]\\s\* "" | string replace -r \^$tokens[2]\\s\* "" | string split ' '
+end
+
+function __fish__get_bun_bun_js_files
+	string split ' ' (bun getcompletes j)
+end
+
+set -l bun_install_boolean_flags yarn production optional development no-save dry-run force no-cache silent verbose global
+set -l bun_install_boolean_flags_descriptions "Write a yarn.lock file (yarn v1)" "Don't install devDependencies" "Add dependency to optionalDependencies" "Add dependency to devDependencies" "Don't update package.json or save a lockfile" "Don't install anything" "Always request the latest versions from the registry & reinstall all dependencies" "Ignore manifest cache entirely" "Don't output anything" "Excessively verbose logging" "Use global folder"
+
+set -l bun_builtin_cmds_without_run dev create help bun upgrade discord install remove add init pm x
+set -l bun_builtin_cmds_accepting_flags create help bun upgrade discord run init link unlink pm x
+
+function __bun_complete_bins_scripts --inherit-variable bun_builtin_cmds_without_run -d "Emit bun completions for bins and scripts"
+    # Do nothing if we already have a builtin subcommand,
+    # or any subcommand other than "run".
+    if __fish_seen_subcommand_from $bun_builtin_cmds_without_run
+    or not __fish_use_subcommand && not __fish_seen_subcommand_from run
+        return
+    end
+    # Do we already have a bin or script subcommand?
+    set -l bins (__fish__get_bun_bins)
+    if __fish_seen_subcommand_from $bins
+        return
+    end
+    # Scripts have descriptions appended with a tab separator.
+    # Strip off descriptions for the purposes of subcommand testing.
+    set -l scripts (__fish__get_bun_scripts)
+    if __fish_seen_subcommand_from (string split \t -f 1 -- $scripts)
+        return
+    end
+    # Emit scripts.
+    for script in $scripts
+        echo $script
+    end
+    # Emit binaries and JS files (but only if we're doing `bun run`).
+    if __fish_seen_subcommand_from run
+        for bin in $bins
+            echo "$bin"\t"package bin"
+        end
+        for file in (__fish__get_bun_bun_js_files)
+            echo "$file"\t"Bun.js"
+        end
+    end
+end
+
+
+# Clear existing completions
+complete -e -c bun
+
+# Dynamically emit scripts and binaries
+complete -c bun -f -a "(__bun_complete_bins_scripts)"
+
+# Complete flags if we have no subcommand or a flag-friendly one.
+set -l flag_applies "__fish_use_subcommand; or __fish_seen_subcommand_from $bun_builtin_cmds_accepting_flags"
+complete -c bun \
+	-n $flag_applies --no-files -s 'u' -l 'origin' -r -d 'Server URL. Rewrites import paths'
+complete -c bun \
+	-n $flag_applies --no-files  -s 'p' -l 'port' -r -d 'Port number to start server from'
+complete -c bun \
+	-n $flag_applies --no-files  -s 'd' -l 'define' -r -d 'Substitute K:V while parsing, e.g. --define process.env.NODE_ENV:\"development\"'
+complete -c bun \
+	-n $flag_applies --no-files  -s 'e' -l 'external' -r -d 'Exclude module from transpilation (can use * wildcards). ex: -e react'
+complete -c bun \
+	-n $flag_applies --no-files -l 'use' -r -d 'Use a framework (ex: next)'
+complete -c bun \
+	-n $flag_applies --no-files -l 'hot' -r -d 'Enable hot reloading in Bun\'s JavaScript runtime'
+
+# Complete dev and create as first subcommand.
+complete -c bun \
+	-n "__fish_use_subcommand" -a 'dev' -d 'Start dev server'
+complete -c bun \
+	-n "__fish_use_subcommand" -a 'create' -f -d 'Create a new project from a template'
+
+# Complete "next" and "react" if we've seen "create".
+complete -c bun \
+	-n "__fish_seen_subcommand_from create" -a 'next' -d 'new Next.js project'
+
+complete -c bun \
+	-n "__fish_seen_subcommand_from create" -a 'react' -d 'new React project'
+
+# Complete "upgrade" as first subcommand.
+complete -c bun \
+	-n "__fish_use_subcommand" -a 'upgrade' -d 'Upgrade bun to the latest version' -x
+# Complete "-h/--help" unconditionally.
+complete -c bun \
+	-s "h" -l "help" -d 'See all commands and flags' -x
+
+# Complete "-v/--version" if we have no subcommand.
+complete -c bun \
+	-n "not __fish_use_subcommand" -l "version" -s "v" -d 'Bun\'s version' -x
+
+# Complete additional subcommands.
+complete -c bun \
+	-n "__fish_use_subcommand" -a 'discord' -d 'Open bun\'s Discord server' -x
+
+
+complete -c bun \
+	-n "__fish_use_subcommand" -a 'bun' -d 'Generate a new bundle'
+
+
+complete -c bun \
+	-n "__fish_seen_subcommand_from bun" -F -d 'Bundle this'
+
+complete -c bun \
+	-n "__fish_seen_subcommand_from create; and __fish_seen_subcommand_from react next" -F -d "Create in directory"
+
+
+complete -c bun \
+	-n "__fish_use_subcommand" -a 'init' -F -d 'Start an empty Bun project'
+
+complete -c bun \
+	-n "__fish_use_subcommand" -a 'install' -f -d 'Install packages from package.json'
+
+complete -c bun \
+	-n "__fish_use_subcommand" -a 'add' -F -d 'Add a package to package.json'
+
+complete -c bun \
+	-n "__fish_use_subcommand" -a 'remove' -F -d 'Remove a package from package.json'
+
+
+for i in (seq (count $bun_install_boolean_flags))
+	complete -c bun \
+		-n "__fish_seen_subcommand_from install add remove" -l "$bun_install_boolean_flags[$i]" -d "$bun_install_boolean_flags_descriptions[$i]"
+end
+
+complete -c bun \
+	-n "__fish_seen_subcommand_from install add remove" -l 'cwd' -d 'Change working directory'
+
+complete -c bun \
+	-n "__fish_seen_subcommand_from install add remove" -l 'cache-dir' -d 'Choose a cache directory (default: $HOME/.bun/install/cache)'
+
+complete -c bun \
+	-n "__fish_seen_subcommand_from add" -d 'Popular' -a '(__fish__get_bun_packages)'
+
+complete -c bun \
+	-n "__fish_seen_subcommand_from add" -d 'History' -a '(__history_completions)'
+
+complete -c bun \
+	-n "__fish_seen_subcommand_from pm; and not __fish_seen_subcommand_from (__fish__get_bun_bins) (__fish__get_bun_scripts) cache;" -a 'bin ls cache hash hash-print hash-string' -f
+
+complete -c bun \
+	-n "__fish_seen_subcommand_from pm; and __fish_seen_subcommand_from cache; and not __fish_seen_subcommand_from (__fish__get_bun_bins) (__fish__get_bun_scripts);" -a 'rm' -f
+
+# Add built-in subcommands with descriptions.
+complete -c bun -n "__fish_use_subcommand" -a "create" -f -d "Create a new project from a template"
+complete -c bun -n "__fish_use_subcommand" -a "build bun" --require-parameter -F -d "Transpile and bundle one or more files"
+complete -c bun -n "__fish_use_subcommand" -a "upgrade" -d "Upgrade Bun"
+complete -c bun -n "__fish_use_subcommand" -a "run" -d "Run a script or package binary"
+complete -c bun -n "__fish_use_subcommand" -a "install" -d "Install dependencies from package.json" -f
+complete -c bun -n "__fish_use_subcommand" -a "remove" -d "Remove a dependency from package.json" -f
+complete -c bun -n "__fish_use_subcommand" -a "add" -d "Add a dependency to package.json" -f
+complete -c bun -n "__fish_use_subcommand" -a "init" -d "Initialize a Bun project in this directory" -f
+complete -c bun -n "__fish_use_subcommand" -a "link" -d "Register or link a local npm package" -f
+complete -c bun -n "__fish_use_subcommand" -a "unlink" -d "Unregister a local npm package" -f
+complete -c bun -n "__fish_use_subcommand" -a "pm" -d "Additional package management utilities" -f
+complete -c bun -n "__fish_use_subcommand" -a "x" -d "Execute a package binary, installing if needed" -f
+complete -c bun -n "__fish_use_subcommand" -a "outdated" -d "Display the latest versions of outdated dependencies" -f
+complete -c bun -n "__fish_use_subcommand" -a "publish" -d "Publish your package from local to npm" -f

config/fish/completions/packwiz.fish

@@ -0,0 +1,177 @@
+# fish completion for packwiz                              -*- shell-script -*-
+
+function __packwiz_debug
+    set -l file "$BASH_COMP_DEBUG_FILE"
+    if test -n "$file"
+        echo "$argv" >> $file
+    end
+end
+
+function __packwiz_perform_completion
+    __packwiz_debug "Starting __packwiz_perform_completion"
+
+    # Extract all args except the last one
+    set -l args (commandline -opc)
+    # Extract the last arg and escape it in case it is a space
+    set -l lastArg (string escape -- (commandline -ct))
+
+    __packwiz_debug "args: $args"
+    __packwiz_debug "last arg: $lastArg"
+
+    # Disable ActiveHelp which is not supported for fish shell
+    set -l requestComp "PACKWIZ_ACTIVE_HELP=0 $args[1] __complete $args[2..-1] $lastArg"
+
+    __packwiz_debug "Calling $requestComp"
+    set -l results (eval $requestComp 2> /dev/null)
+
+    # Some programs may output extra empty lines after the directive.
+    # Let's ignore them or else it will break completion.
+    # Ref: https://github.com/spf13/cobra/issues/1279
+    for line in $results[-1..1]
+        if test (string trim -- $line) = ""
+            # Found an empty line, remove it
+            set results $results[1..-2]
+        else
+            # Found non-empty line, we have our proper output
+            break
+        end
+    end
+
+    set -l comps $results[1..-2]
+    set -l directiveLine $results[-1]
+
+    # For Fish, when completing a flag with an = (e.g., <program> -n=<TAB>)
+    # completions must be prefixed with the flag
+    set -l flagPrefix (string match -r -- '-.*=' "$lastArg")
+
+    __packwiz_debug "Comps: $comps"
+    __packwiz_debug "DirectiveLine: $directiveLine"
+    __packwiz_debug "flagPrefix: $flagPrefix"
+
+    for comp in $comps
+        printf "%s%s\n" "$flagPrefix" "$comp"
+    end
+
+    printf "%s\n" "$directiveLine"
+end
+
+# This function does two things:
+# - Obtain the completions and store them in the global __packwiz_comp_results
+# - Return false if file completion should be performed
+function __packwiz_prepare_completions
+    __packwiz_debug ""
+    __packwiz_debug "========= starting completion logic =========="
+
+    # Start fresh
+    set --erase __packwiz_comp_results
+
+    set -l results (__packwiz_perform_completion)
+    __packwiz_debug "Completion results: $results"
+
+    if test -z "$results"
+        __packwiz_debug "No completion, probably due to a failure"
+        # Might as well do file completion, in case it helps
+        return 1
+    end
+
+    set -l directive (string sub --start 2 $results[-1])
+    set --global __packwiz_comp_results $results[1..-2]
+
+    __packwiz_debug "Completions are: $__packwiz_comp_results"
+    __packwiz_debug "Directive is: $directive"
+
+    set -l shellCompDirectiveError 1
+    set -l shellCompDirectiveNoSpace 2
+    set -l shellCompDirectiveNoFileComp 4
+    set -l shellCompDirectiveFilterFileExt 8
+    set -l shellCompDirectiveFilterDirs 16
+
+    if test -z "$directive"
+        set directive 0
+    end
+
+    set -l compErr (math (math --scale 0 $directive / $shellCompDirectiveError) % 2)
+    if test $compErr -eq 1
+        __packwiz_debug "Received error directive: aborting."
+        # Might as well do file completion, in case it helps
+        return 1
+    end
+
+    set -l filefilter (math (math --scale 0 $directive / $shellCompDirectiveFilterFileExt) % 2)
+    set -l dirfilter (math (math --scale 0 $directive / $shellCompDirectiveFilterDirs) % 2)
+    if test $filefilter -eq 1; or test $dirfilter -eq 1
+        __packwiz_debug "File extension filtering or directory filtering not supported"
+        # Do full file completion instead
+        return 1
+    end
+
+    set -l nospace (math (math --scale 0 $directive / $shellCompDirectiveNoSpace) % 2)
+    set -l nofiles (math (math --scale 0 $directive / $shellCompDirectiveNoFileComp) % 2)
+
+    __packwiz_debug "nospace: $nospace, nofiles: $nofiles"
+
+    # If we want to prevent a space, or if file completion is NOT disabled,
+    # we need to count the number of valid completions.
+    # To do so, we will filter on prefix as the completions we have received
+    # may not already be filtered so as to allow fish to match on different
+    # criteria than the prefix.
+    if test $nospace -ne 0; or test $nofiles -eq 0
+        set -l prefix (commandline -t | string escape --style=regex)
+        __packwiz_debug "prefix: $prefix"
+
+        set -l completions (string match -r -- "^$prefix.*" $__packwiz_comp_results)
+        set --global __packwiz_comp_results $completions
+        __packwiz_debug "Filtered completions are: $__packwiz_comp_results"
+
+        # Important not to quote the variable for count to work
+        set -l numComps (count $__packwiz_comp_results)
+        __packwiz_debug "numComps: $numComps"
+
+        if test $numComps -eq 1; and test $nospace -ne 0
+            # We must first split on \t to get rid of the descriptions to be
+            # able to check what the actual completion will be.
+            # We don't need descriptions anyway since there is only a single
+            # real completion which the shell will expand immediately.
+            set -l split (string split --max 1 \t $__packwiz_comp_results[1])
+
+            # Fish won't add a space if the completion ends with any
+            # of the following characters: @=/:.,
+            set -l lastChar (string sub -s -1 -- $split)
+            if not string match -r -q "[@=/:.,]" -- "$lastChar"
+                # In other cases, to support the "nospace" directive we trick the shell
+                # by outputting an extra, longer completion.
+                __packwiz_debug "Adding second completion to perform nospace directive"
+                set --global __packwiz_comp_results $split[1] $split[1].
+                __packwiz_debug "Completions are now: $__packwiz_comp_results"
+            end
+        end
+
+        if test $numComps -eq 0; and test $nofiles -eq 0
+            # To be consistent with bash and zsh, we only trigger file
+            # completion when there are no other completions
+            __packwiz_debug "Requesting file completion"
+            return 1
+        end
+    end
+
+    return 0
+end
+
+# Since Fish completions are only loaded once the user triggers them, we trigger them ourselves
+# so we can properly delete any completions provided by another script.
+# Only do this if the program can be found, or else fish may print some errors; besides,
+# the existing completions will only be loaded if the program can be found.
+if type -q "packwiz"
+    # The space after the program name is essential to trigger completion for the program
+    # and not completion of the program name itself.
+    # Also, we use '> /dev/null 2>&1' since '&>' is not supported in older versions of fish.
+    complete --do-complete "packwiz " > /dev/null 2>&1
+end
+
+# Remove any pre-existing completions for the program since we will be handling all of them.
+complete -c packwiz -e
+
+# The call to __packwiz_prepare_completions will setup __packwiz_comp_results
+# which provides the program's completion choices.
+complete -c packwiz -n '__packwiz_prepare_completions' -f -a '$__packwiz_comp_results'
+

config/fish/config.fish

@@ -0,0 +1,14 @@
+if status is-interactive
+    # Commands to run in interactive sessions can go here
+    if tty | string match "/dev/tty1"
+	    $HOME/start
+    end
+end
+
+# bun
+set --export BUN_INSTALL "$HOME/.bun"
+set --export GOPATH "$HOME/go"
+set --export PATH $BUN_INSTALL/bin $GOPATH/bin $HOME/.local/bin $PATH
+
+# gpg
+export GPG_TTY=$(tty)

config/fish/fish_variables

@@ -0,0 +1,31 @@
+# This file contains fish universal variable definitions.
+# VERSION: 3.0
+SETUVAR __fish_initialized:3800
+SETUVAR fish_color_autosuggestion:brblack
+SETUVAR fish_color_cancel:\x2dr
+SETUVAR fish_color_command:normal
+SETUVAR fish_color_comment:red
+SETUVAR fish_color_cwd:green
+SETUVAR fish_color_cwd_root:red
+SETUVAR fish_color_end:green
+SETUVAR fish_color_error:brred
+SETUVAR fish_color_escape:brcyan
+SETUVAR fish_color_history_current:\x2d\x2dbold
+SETUVAR fish_color_host:normal
+SETUVAR fish_color_host_remote:yellow
+SETUVAR fish_color_normal:normal
+SETUVAR fish_color_operator:brcyan
+SETUVAR fish_color_param:cyan
+SETUVAR fish_color_quote:yellow
+SETUVAR fish_color_redirection:cyan\x1e\x2d\x2dbold
+SETUVAR fish_color_search_match:white\x1e\x2d\x2dbackground\x3dbrblack
+SETUVAR fish_color_selection:white\x1e\x2d\x2dbold\x1e\x2d\x2dbackground\x3dbrblack
+SETUVAR fish_color_status:red
+SETUVAR fish_color_user:brgreen
+SETUVAR fish_color_valid_path:\x2d\x2dunderline
+SETUVAR fish_key_bindings:fish_default_key_bindings
+SETUVAR fish_pager_color_completion:normal
+SETUVAR fish_pager_color_description:yellow\x1e\x2di
+SETUVAR fish_pager_color_prefix:normal\x1e\x2d\x2dbold\x1e\x2d\x2dunderline
+SETUVAR fish_pager_color_progress:brwhite\x1e\x2d\x2dbackground\x3dcyan
+SETUVAR fish_pager_color_selected_background:\x2dr

config/fish/functions/fish_greeting.fish

@@ -0,0 +1,21 @@
+function fish_greeting
+    if not set -q fish_greeting
+        set -l line1 (printf (_ 'Welcome to %sanhgelus-void%s.') (set_color "#95d5b2" green) (set_color normal))
+        set -l line2 \n(printf (_ 'Workstation powered by the %svoid%s.') (set_color green) (set_color normal))
+        set -g fish_greeting "$line1$line2"
+    end
+
+    if set -q fish_private_mode
+        set -l line (_ "fish is running in private mode, history will not be persisted.")
+        if set -q fish_greeting[1]
+            set -g fish_greeting $fish_greeting\n$line
+        else
+            set -g fish_greeting $line
+        end
+    end
+
+    # The greeting used to be skipped when fish_greeting was empty (not just undefined)
+    # Keep it that way to not print superfluous newlines on old configuration
+    test -n "$fish_greeting"
+    and echo $fish_greeting
+end

config/fish/functions/fish_prompt.fish

@@ -0,0 +1,34 @@
+# name: Default
+# author: Lily Ballard
+
+function fish_prompt --description 'Write out the prompt'
+    set -l last_pipestatus $pipestatus
+    set -lx __fish_last_status $status # Export for __fish_print_pipestatus.
+    set -l normal (set_color normal)
+    set -q fish_color_status
+    or set -g fish_color_status red
+
+    # Color the prompt differently when we're root
+    set -l color_cwd "#ffd6ff" 
+    set -l suffix '>'
+    if functions -q fish_is_root_user; and fish_is_root_user
+        if set -q fish_color_cwd_root
+            set color_cwd $fish_color_cwd_root
+        end
+        set suffix '#'
+    end
+
+    # Write pipestatus
+    # If the status was carried over (if no command is issued or if `set` leaves the status untouched), don't bold it.
+    set -l bold_flag --bold
+    set -q __fish_prompt_status_generation; or set -g __fish_prompt_status_generation $status_generation
+    if test $__fish_prompt_status_generation = $status_generation
+        set bold_flag
+    end
+    set __fish_prompt_status_generation $status_generation
+    set -l status_color (set_color $fish_color_status)
+    set -l statusb_color (set_color $bold_flag $fish_color_status)
+    set -l prompt_status (__fish_print_pipestatus "[" "]" "|" "$status_color" "$statusb_color" $last_pipestatus)
+
+    echo -n -s (prompt_login)' ' (set_color $color_cwd) (prompt_pwd) $normal (fish_vcs_prompt) $normal " "$prompt_status $suffix " "
+end

config/fish/functions/prompt_login.fish

@@ -0,0 +1,28 @@
+function prompt_login --description "display user name for the prompt"
+    if not set -q __fish_machine
+        set -g __fish_machine
+        set -l debian_chroot $debian_chroot
+
+        if test -r /etc/debian_chroot
+            set debian_chroot (cat /etc/debian_chroot)
+        end
+
+        if set -q debian_chroot[1]
+            and test -n "$debian_chroot"
+            set -g __fish_machine "(chroot:$debian_chroot)"
+        end
+    end
+
+    # Prepend the chroot environment if present
+    if set -q __fish_machine[1]
+        echo -n -s (set_color yellow) "$__fish_machine" (set_color normal) ' '
+    end
+
+    # If we're running via SSH, change the host color.
+    set -l color_host "#95d5b2" 
+    if set -q SSH_TTY; and set -q fish_color_host_remote
+        set color_host $fish_color_host_remote
+    end
+
+    echo -n -s (set_color "#ffd6ff" green) "$USER" (set_color normal) @ (set_color $color_host) (prompt_hostname) (set_color normal)
+end